討論區列表
元大MultiCharts
一般模式
討論串模式
標題:
[發表] 據說有90%勝率的交易系統樣本
by 2011-10-12 15:00:52
0
暱稱:
肥貓
信箱:不顯示
成就:發文(0) / 回文(0) / 推薦(0)
據說有90%勝率的交易系統樣本
A system giving over 90% profitable trades.
{****************************************************
The Simplest System #3 with Money Management.
Copyright (c) 2002 DT
****************************************************}
Input: Price((H+L)*.5), {中間價}
PtUp(4.), PtDn(4.), {Max correction to change trend}
MM_Model(2), {1 = % Risk Model; 2 = % Volatility Model;
3 = Drawdown Model; 4 = Kelly Model; 5 = Williams" Model;
6 = Fixed Ratio Model; 7= Market Money Model}
MM(1), {% Risk parameter}
MM_add(0), {% Risk for playing market money; 0 to disactivate}
MaxVolat(100), {% Risk for playing market money; 100 to disactivate}
MaxDD(20), {% Drawdown 資金回撤率}
InitCapital(100000); {Initial capital to trade 開始資金}
Vars: LL(99999), HH(0), Trend(0), Volat(TrueRange);
Vars: MP(0), Risk(Range), Num(1), add_num(0), red_num(0), FRDelta(0),
DD(0),
Equity(InitCapital), TotalEquity(InitCapital), EqTop(InitCapital),
AssuredProfit(0), HPositionProfit(0), Kelly(0);
MP = MarketPosition;
Volat = .5 * TrueRange + .5*Volat[1];
if MP <= 0 then begin
if Price < LL then LL = Price;
if Price cross above LL*(1 + PtUp*.01) then begin
Trend = 1;
HH = Price;
end;
end;
if MP >= 0 then begin
if Price > HH then HH = Price;
if Price cross below HH*(1 - PtDn*.01) then begin
Trend = -1;
LL = Price;
end;
end;
If trend = 1 then Risk = PtDn * .01 * close {+ Slippage};
If trend = -1 then Risk = PtUp * .01 * close {+ Slippage};
HPositionProfit = maxlist( OpenPositionProfit, HPositionProfit);
AssuredProfit = HPositionProfit - Risk;
Equity = InitCapital + NetProfit;
TotalEquity = Equity + OpenPositionProfit;
EqTop = MaxList(EqTop, TotalEquity);
if MM_Model = 1 then { % Risk Model }
Num = floor(MM * Equity *.01/Risk);
if MM_Model = 2 then { % Volatility Model }
Num = floor(MM * Equity *.01/ Volat / BigPointValue );
if MM_Model = 3 then begin { Drawdown Model }
Num = floor(MM * (Equity - (1 - MaxDD*.01) * EqTop) * .01 / Volat /
BigPointValue);
end;
if MM_Model = 4 then begin { Kelly Model }
If TotalTrades > 20 and GrossProfit > 0 then
Kelly = NumWinTrades/TotalTrades * (1 - GrossLoss/GrossProfit)
else
Kelly = 0.1;
if Kelly > .9 then Kelly = .9;
Num = floor(MM * Kelly * Equity * .01 / Risk);
{Print(Kelly);}
end;
if MM_Model = 5 then begin { Larry Williams" Model }
value11 = MaxList(-LargestLosTrade / MaxList(CurrentContracts, 1) , Risk);
Num = floor(MM * Equity *.01 / value11);
end;
if MM_Model = 6 then begin { Fixed Ratio Model }
{ DD = MaxList(DD, (EqTop - TotalEquity)/MaxList(CurrentContracts, 1)) ; {Max
Drawdown}
if TotalTrades > 20 and DD > 0 then FRDelta = MM * DD *.01
else }
FRDelta = MM * volat * BigPointValue * .01; {Delta}
value12 = MaxList(Equity - .5*close*(close + FRDelta)/FRDelta, 0.25);
Num = floor(SquareRoot(2*value12/FRDelta + .25) + .5);
end;
if MM_Model = 7 then { Playing the market money }
num = floor((MM * (InitCapital + MinList(NetProfit, 0)) + MM_add *
MaxList(NetProfit, 0)) * .01 / Volat / BigPointValue);
{ Entries}
if trend = 1 and trend[1] <> 1 then buy("Trend.LE") num contracts at market;
if trend = -1 and trend[1] <> -1 then sell("Trend.SE") num contracts at market;
add_num = floor( MM_add * AssuredProfit * .01/ Volat / BigPointValue);
{ Assured Profit Pyramiding }
if add_num > 0 and OpenPositionProfit > Volat * BigPointValue then begin
if Trend = 1 and MP = 1 then buy("Add.LE") add_num contracts at market;
if Trend = -1 and MP = -1 then sell("Add.SE") add_num contracts at market;
end;
red_num = floor((CurrentContracts * Volat * BigPointValue - MaxVolat *
TotalEquity * .01)/ close);
if red_num > 0 then begin
if Trend = 1 and MP = 1 then exitlong("Red.LX") red_num contracts at market;
if Trend = -1 and MP = -1 then exitshort("Red.SX") red_num contracts at
market;
end;
轉錄自
http://mypaper.pchome.com.tw/tony168324/post/1322080257
在MC裡好像不能用,語法錯誤,有人可以修正這個問題?
第一頁
上一頁
下一頁
最後頁
討論區列表
元大MultiCharts
MultiCharts
│
討論區
│
會員專區
│
教學講座
│
支援與服務
│
產品購買
│
申請試用
All rights for MultiCharts Trading Software are reserved by MultiCharts, LLC
凱衛資訊股份有限公司 營利事業統一編號(21261212) 著作權所有 本網站最佳瀏覽解析度為 1024 x 768
隱私權政策
│
網站安全政策
│
著作權說明
若不清楚點選圖片更新驗證碼
註冊帳號
忘記密碼
解除鎖定